Utente:Toobaz/Immagini

Intendo spiegare in questa pagina il modo in cui ho realizzato alcune immagini poi caricate tra i commons, dato che so per esperienza quanto anche le migliori documentazioni dei migliori programmi non aiutino ad iniziare quanto un esempio pratico.

Gnuplot

Gnuplot ha il lato positivo (ma dipende dai gusti ;-) ) che può essere utilizzato da shell (ma non solo). Gli script (le istruzioni per realizzare le immagini) sono semplicissimi file di testo tutto sommato abbastanza intuitivi.

Supporta le funzioni in 2 e 3 dimensioni, anche parametriche.

Un esempio: anelli e nastri di Möbius.

Di seguito, il listato di uno script pronto per l'utilizzo che serve per creare anelli e nastri di Möbius, e che io ho utilizzato per l'articolo sugli anelli.

# per stabilire la modalità di output
set terminal png transparent size 420,320

# qui si dichiara e inizializza le variabili
fase = -6		#permette di ruotare la figura attorno al suo centro
larg = 4		#il raggio della figura
band = 1		#la larghezza del nastro
giri = 1		#il numero di torsioni (se è pari, viene un anello, se è dispari, un nastro di Möbius)

# qui si dichiara che si utilizza una raffigurazione parametrica, e si stabilisce il dominio della parametrizzazione
set param
set vrange [band*-1:band]
set urange [-3.14:3.14]

# questi sono solo accorgimenti estetici
unset xtics
unset ytics
unset ztics
unset border
set view 29, 9
set isosamples 40
set hidden3d

# questa è la funzione vera e propria, con i tre campi separati da virgole
splot cos(u+fase)*(larg+v*sin(giri*(u+fase)/2)), sin(u-fase)*(larg+v*sin(giri*(u+fase)/2)), v*cos(giri*(u+fase)/2) title ""

Una volta salvato questo script in nomescript.gp, lo si fa processare a Gnuplot con questo comando:

gnuplot nomescript.gp > nomeimmagine.png

Di seguito, alcuni esempi di output:

• 
  Con giri=0 otteniamo un semplice anello.
• 
  Con giri=1, un Nastro di Möbius "classico".
• 
  giri=2: un anello "rigirato".
• 
  Con giri=3, un nastro di Möbius "rigirato".
• 
  giri=4, e si può andare avanti a piacere...

Osserviamo che ogni volta che giri è dispari il colore cambia a metà di una faccia: è inevitabile, dato che la faccia è una sola ma con un colore solo la figura sarebbe difficilmente riconoscibile.